mixin template FinalCtor()

{

    mixin(() {

        import std.traits : FieldNameTuple;

        static assert(FieldNameTuple!(typeof(this)).length == typeof(typeof(this).tupleof).length);

        string result = "this(";

        static foreach (i; 0 .. typeof(typeof(this).tupleof).length)

            result ~= mixin(`"typeof(this.tupleof)[`, i, `] `, FieldNameTuple!(typeof(this))[i], `, "`);

        return result ~ ")

        {

            import std.traits : FieldNameTuple;

            static foreach (i; 0 .. this.tupleof.length)

                this.tupleof[i] = mixin(FieldNameTuple!(typeof(this))[i]);

        }";

    }());

}

​

struct S

{

    int x;

    double y;

    string z;

    mixin FinalCtor;

}

​

void main()

{

    static assert( __traits(compiles, S()));

    static assert(!__traits(compiles, S(1)));

    static assert(!__traits(compiles, S(1, 2.0)));

    static assert( __traits(compiles, S(1, 2.0, "three")));

    S s = S(1, 2.0, "three"); // feel free to remove arguments and see the error messages.

}