struct BufferedStdout

{

    import std.array : appender;

​

    private auto _outputBuffer = appender!(char[]);

​

    ~this()

    {

        import std.stdio : write;

        write(_outputBuffer.data);

        _outputBuffer.clear;

    }

​

    void appendln(T)(T stuff)

    {

        import std.range : put;

        put(_outputBuffer, stuff);

        put(_outputBuffer, "\n");

    }

}

​

/** Tuple unpacker

 *

 * Usage: myTuple.unpack!((x, y) => f(x, y));

 *

 * Arguments are bound by order; names are irrelevant.

 *

 * Based on 'tupArg' by Dukc:

 *   https://forum.dlang.org/thread/rkfezigmrvuzkztxqqxy@forum.dlang.org

 */

template unpack(alias func)

{

    import std.typecons: isTuple;

​

    auto unpack(TupleType)(TupleType tup)

        if (isTuple!TupleType)

    {

        return func(tup.expand);

    }

}

​

​

void foo(BufferedStdout output)

{

    import std.algorithm : each;

    import std.conv : to;

    import std.range: generate, takeExactly, zip, repeat;

    import std.random: Random, uniform, unpredictableSeed;

​

    auto randomGenerator = Random(unpredictableSeed);

    auto randomNumbers = generate!(() => uniform(0, 1000, randomGenerator));

    auto tenRandomNumbers = randomNumbers.takeExactly(10);

    tenRandomNumbers

        .zip(repeat(output))

        .each!(unpack!((n, output) => output.appendln(n.to!string)));

}

​

void main(string[] args)

{

    foo(BufferedStdout());

}