/+dub.sdl:

dependency "mir-random" version="~>0.4.3"

+/

import std.stdio;

​

/++

Converts an N-dimensional variable to a fixed-dimensional variable.

+/

auto specifyDimension(ReturnType, NDVariable)(NDVariable vr)

    if (__traits(isStaticArray, ReturnType) && __traits(compiles, {static assert(NDVariable.isRandomVariable);}))

{

    import mir.random : isSaturatedRandomEngine;

    import mir.random.variable : isRandomVariable;

    static struct V

    {

        enum bool isRandomVariable = true;

        NDVariable vr;

        ReturnType opCall(G)(scope ref G gen) if (isSaturatedRandomEngine!G)

        {

            ReturnType ret;

            vr(gen, ret[]);

            return ret;

        }

​

        ReturnType opCall(G)(scope G* gen) if (isSaturatedRandomEngine!G)

        {

            return opCall!(G)(*gen);

        }

    }

    static assert(isRandomVariable!V);

    V v = { vr };

    return v;

}

​

void main()

{

    import mir.random : Random, threadLocalPtr;

    import mir.random.ndvariable : multivariateNormalVar;

    import mir.random.algorithm : range;

    import mir.ndslice.slice : sliced;

    import std.range : take;

​

    auto mu = [10.0, 0.0].sliced;

    auto sigma = [2.0, -1.5, -1.5, 2.0].sliced(2,2);

​

    Random* rng = threadLocalPtr!Random;

    auto sample = rng

                .range(multivariateNormalVar(mu, sigma).specifyDimension!(double[2]))

                .take(10);

    writeln(sample);

}

​

​