import core.stdc.stdio;

import std.traits;

​

struct interp(string s)

{

    static string toString() { return s; }

}

​

alias printf = core.stdc.stdio.printf;

​

auto printf(Args...)(Args args) if (isInstanceOf!(interp, Args[0]))

{

    alias genFormat = function() {

        string result;

        foreach(T; Args)

            static if(isInstanceOf!(interp, T))

                result ~= T.toString();

            else static if(is(T == int))

                result ~= "%d";

            else static if(is(T : const(char)[]))

                result ~= "%.*s";

            else static if(is(T == float) || is(T == double))

                result ~= "%f";

            // .. and so on

        return result ~ "\0";

    };

    static immutable formatStr = genFormat();

    alias genMixin = function() {

        string result = "return core.stdc.stdio.printf(formatStr.ptr";

        foreach(i, T; Args)

            static if(!isInstanceOf!(interp, T)){

                static if(is(T : const(char)[]))

                    result ~= ", cast(int)args[" ~ i.stringof ~ "].length, args[" ~ i.stringof ~ "].ptr";

                else

                    result ~= ", args[" ~ i.stringof ~ "]";

            }

        return result ~ ");";

    };

    mixin(genMixin());

}

extern(C) void main()

{

    string name = "Walter";

    int age = 42;

    // equivalent of printf(i"Hello, ${name}, you are ${age} years old.\n");

    printf(interp!"Hello, "(), name, interp!", you are "(), age, interp!" years old.\n"());

    printf("And normal printf works too, %s\n", name.ptr);

}