auto loop(alias rangeMaker, Range)(Range r)

{

    import std.typecons : tuple;

    enum rIsTuple = is(typeof(r.front.expand));

    static if(rIsTuple)

        alias Next = typeof(rangeMaker(r.front.expand));

    else

        alias Next = typeof(rangeMaker(r.front));

    static struct Looper

    {

        Range x;

        Next n;

        auto front(){

            static if(rIsTuple)

                return tuple(x.front.expand, n.front);

            else

                return tuple(x.front, n.front);

        }

        private void prime()

        {

            while(n.empty)

            {

                x.popFront;

                if(!x.empty)

                {

                    static if(rIsTuple)

                        n = rangeMaker(x.front.expand);

                    else

                        n = rangeMaker(x.front);

                }

            }

        }

        void popFront()

        {

            n.popFront;

            prime();

        }

        bool empty()

        {

            return x.empty;

        }

    }

    if(r.empty)

        return Looper(r, Next.init);

    static if(rIsTuple)

        auto innerRange = rangeMaker(r.front.expand);

    else

        auto innerRange = rangeMaker(r.front);

    auto result = Looper(r, innerRange);

    result.prime();

    return result;

}

​

void main()

{

    import std.range;

    import std.algorithm;

    import std.stdio;

    foreach(z, x, y; size_t(1).recurrence!"a[n-1] + 1"

            .loop!(z => iota(1, z))

            .loop!((z, x) => iota(x, z))

            .filter!(t => t[1]*t[1] + t[2]*t[2] == t[0]*t[0])

            .take(100))

    {

        writefln("%s %s %s", x, y, z);

    }

}