import std.traits : isSomeFunction;

​

bool isStronglyPure(F...)()

if (F.length == 1 && isSomeFunction!F)

{

    import std.traits : arity, isFunctionPointer, isDelegate,

        isAssociativeArray, isPointer, Parameters;

    import std.algorithm : canFind;

​

    static if (!__traits(getFunctionAttributes, F).canFind("pure"))

        return false;

​

    enum length = arity!F;

​

    static foreach (i; 0 .. length) {

        if (__traits(getParameterStorageClasses, F, i).canFind("ref", "out"))

            return false;

        if (is(Parameters!F[i] == class)

            || isFunctionPointer!(Parameters!F[i])

            || isDelegate!(Parameters!F[i])

            || isAssociativeArray!(Parameters!F[i])

            || isPointer!(Parameters!F[i]))

            return false;

    }

​

    return true;

}

​

void e() pure

{

}

​

int f(int x) pure

{

    return x + 1;

}

​

int g(ref int x) pure

{

    return x + 1;

}

​

void h(out int x) pure

{

    x = 0;

}

​

class Test

{

    void i(Test other) pure

    {

        f(1);

        other = this;

    }

}

​

void main()

{

    static assert(isStronglyPure!f);

    static assert(!isStronglyPure!g);

    static assert(!isStronglyPure!h);

    static assert(!isStronglyPure!(Test.i));

}